data.open.ac.uk - Changelog

This page includes a selection of recently published bugfix and improvements on data.open.ac.uk. You can also subscribe to the related RSS feed.

Entity resolution includes document license
Mon, 07 Mar 2016

Today we added information about the document resource (include licensing) in the data obtained when resolving Linked Data URIs.

What does it mean? For example, resolving URI "http://data.open.ac.uk/course/offer/kg002-gr-2016c" (with header Accept: application/rdf+xml) the client is redirected to "http://data.open.ac.uk/resource/course/offer/kg002-gr-2016c", to obtain what follows:

 <rdf:RDF
     xmlns:rdf="http://www.w3.org/1999/02/22-rdf-syntax-ns#"
     xmlns:j.0="http://purl.org/dc/terms/"
     xmlns:j.1="http://purl.org/goodrelations/v1#"
     xmlns:j.2="http://data.open.ac.uk/saou/ontology#"
     xmlns:rdfs="http://www.w3.org/2000/01/rdf-schema#"
     xmlns:j.3="http://xmlns.com/foaf/0.1/"
     xmlns:j.4="http://rdfs.org/ns/void#">
   <j.3:Document rdf:about="http://data.open.ac.uk/resource/course/offer/kg002-gr-2016c">
     <j.0:license rdf:resource="http://creativecommons.org/licenses/by/3.0/"/>
     <j.3:primaryTopic>
       <j.1:Offering rdf:about="http://data.open.ac.uk/course/offer/kg002-gr-2016c">
         <j.1:availableAtOrFrom rdf:resource="http://sws.geonames.org/390903/"/>
         <j.2:validForPresentation rdf:resource="http://data.open.ac.uk/course/presentation/kg002-2016c"/>
         <j.4:inDataset rdf:resource="http://data.open.ac.uk/context/course"/>
         <j.1:availabilityEnds rdf:datatype="http://www.w3.org/2001/XMLSchema#dateTime"
         >2016-03-01T00:00:00Z</j.1:availabilityEnds>
         <j.1:hasPriceSpecification rdf:resource="http://data.open.ac.uk/course/price/kg002-gr-2016c"/>
         <j.1:includes rdf:resource="http://data.open.ac.uk/course/kg002"/>
         <rdfs:label>Offer for course KG002: &amp;pound;185.00 in GR for presentation 2016C</rdfs:label>
       </j.1:Offering>
     </j.3:primaryTopic>
   </j.3:Document>
 </rdf:RDF>

Note: the URIs representing resources (and not entities) are not represented in the data store, so you cannot find them by querying the SPARQL endpoint. In our example, there is not triple

 <http://data.open.ac.uk/resource/course/offer/kg002-gr-2016c> a foaf:Document

but of course you'll find everything about "http://data.open.ac.uk/course/offer/kg002-gr-2016c", as usual.

New data! Listening Experience Database early access snapshots
Mon, 15 Sep 2014

As of September 15, 2014, the Listening Experience Database (LED, www.open.ac.uk/Arts/LED) has disclosed its dataset as Linked Open Data. This is updated once a day with the latest changes on the LED website. The name of the graph is http://data.open.ac.uk/context/led.

Example queries below: Get all the people who have written about listening experiences they took part in

## Get all the people who have written about listening experiences they took part in
PREFIX event: <http://purl.org/NET/c4dm/event.owl#>
PREFIX led: <http://led.kmi.open.ac.uk/term/>
PREFIX rdfs: <http://www.w3.org/2000/01/rdf-schema#>
PREFIX schema: <http://schema.org/>
SELECT DISTINCT ?person ?label
WHERE {
   [] a led:ListeningExperience 
      ; led:is_reported_in/schema:author ?person
      ; event:agent ?person .
   ?person rdfs:label ?label
} ORDER BY ?person

Get all the places where national anthems were performed

## Get all the places where national anthems were performed
PREFIX dbpedia-owl: <http://dbpedia.org/ontology/>
PREFIX event: <http://purl.org/NET/c4dm/event.owl#>
PREFIX rdfs: <http://www.w3.org/2000/01/rdf-schema#>
SELECT ?place (COUNT(DISTINCT ?performance) as ?performances)
WHERE {
   ?performance event:place ?place
      ; dbpedia-owl:genre <http://dbpedia.org/resource/National_anthem>
} GROUP BY ?place

New Data! OU audio boos...
Fri, 05 Sep 2014

We are happy to announce new data at data.open.ac.uk: the OU audio content published at http://audioboo.fm.

These are the playlists in the science channel:

PREFIX rdfs: <http://www.w3.org/2000/01/rdf-schema#>
PREFIX ab: <http://data.open.ac.uk/audioboo/ontology/>
PREFIX dcterms: <http://purl.org/dc/terms/>
select ?playlist ?label (count(?post) as ?posts)
from <http://data.open.ac.uk/context/audioboo>
where {
  ?playlist a ab:AudioBooPlaylist ;
    rdfs:label ?label ;
        dcterms:hasPart ?post ;
        ab:inChannel <http://data.open.ac.uk/audioboo/channel/openuniversityscience> .
} GROUP BY ?playlist ?label

Enjoy!

New data! The OU Key Information Set from Hesa/LinkedUp
Tue, 20 May 2014

Recently the LinkedUP project (http://linkedup-project.eu/) published the Unistats database as Linked Open Data. Today we publish the slice about The Open University. The name of the graph is http://data.open.ac.uk/context/kis:

PREFIX xsd: <http://www.w3.org/2001/XMLSchema#>
PREFIX qb: <http://purl.org/linked-data/cube#>
PREFIX kis: <http://data.linkedu.eu/kis/ontology/>
PREFIX rdfs: <http://www.w3.org/2000/01/rdf-schema#>

select ?Course ?Job ?Population ?Aggregation 
from <http://data.open.ac.uk/context/kis> 
where {
  ?row a qb:Observation .
  ?row qb:dataSet <http://data.linkedu.eu/kis/dataset/commonJobs> .
  ?row kis:population ?Population .
  ?row kis:aggregation ?Aggregation .
  ?row kis:job/rdfs:label ?Job .
  ?row kis:course/kis:courseId ?Course .
}

Youtube videos now related to OU courses and qualifications
Thu, 12 Dec 2013

The http://data.open.ac.uk/context/youtube context is where we collect data about the presence of the Open University on YouTube. We now extract content from all OU channels. Videos and Playlists are now linked to courses and qualifications.

Try the following query, to see OU content related to a YouTube video using the YouTube video id (from the URL, eg http://www.youtube.com/watch?v=SYry6PYsL8o, just take "SYry6PYsL8o"):

  prefix rdf: <http://www.w3.org/1999/02/22-rdf-syntax-ns#>
  prefix podcast: <http://data.open.ac.uk/podcast/ontology/>
  prefix yt: <http://data.open.ac.uk/youtube/ontology/>
  prefix rdfs: <http://www.w3.org/2000/01/rdf-schema#>
  prefix rkb: <http://courseware.rkbexplorer.com/ontologies/courseware#>
  prefix saou: <http://data.open.ac.uk/saou/ontology#>
  prefix dbp: <http://dbpedia.org/property/>
  prefix media: <http://purl.org/media#>
  prefix olearn: <http://data.open.ac.uk/openlearn/ontology/>
  prefix mlo: <http://purl.org/net/mlo/>
  prefix bazaar: <http://digitalbazaar.com/media/>
  prefix schema: <http://schema.org/>

 SELECT 
  distinct
  (?related as ?identifier)
  ?type
  ?label
  (str(?location) as ?link)

  FROM <http://data.open.ac.uk/context/youtube>
  FROM <http://data.open.ac.uk/context/podcast>
  FROM <http://data.open.ac.uk/context/openlearn>
  FROM <http://data.open.ac.uk/context/course>
  FROM <http://data.open.ac.uk/context/qualification>
  WHERE
  { 
 ?x schema:productID "SYry6PYsL8o" . # change the youtube id to any OU youtube video
 ?x  yt:relatesToCourse ?course .
  {
       # related video podcasts
           ?related podcast:relatesToCourse ?course .
           ?related a podcast:VideoPodcast .
       ?related rdfs:label ?label .
           optional { ?related bazaar:download ?location }
       BIND( "VideoPodcast" as ?type ) .
     } union {
       # related audio podcasts
           ?related podcast:relatesToCourse ?course . 
           ?related a podcast:AudioPodcast .
       ?related rdfs:label ?label .
           optional { ?related bazaar:download ?location }
       BIND( "AudioPodcast" as ?type ) .
     } union {
       # related openlearn units
           ?related a olearn:OpenLearnUnit .
       ?related olearn:relatesToCourse ?course  .
       BIND( "OpenLearnUnit" as ?type ) .
           ?related <http://dbpedia.org/property/url> ?location .
       ?related rdfs:label ?label .
     } union {
           # related qualifications (compulsory course)
           ?related a mlo:qualification .
           ?related saou:hasPathway/saou:hasStage/saou:includesCompulsoryCourse ?course  .
       BIND( "Qualification" as ?type ) .
       ?related rdfs:label ?label .
       ?related mlo:url ?location 
         }
 }

Or can grab a YouTube code directly from the data:

  prefix yt: <http://data.open.ac.uk/youtube/ontology/>
  PREFIX dct: <http://purl.org/dc/terms/>
  prefix schema: <http://schema.org/>

 SELECT 
 DISTINCT ?code

  FROM <http://data.open.ac.uk/context/youtube>
  WHERE
  { 

    ?x schema:productID ?code ;
           dct:published ?published ;
           yt:relatesToCourse []

  } order by desc (?published)

Number of assessments and set books (hasBook) added to OU courses
Wed, 27 Nov 2013

We added some information to courses, namely:

  • number of TMA essays: http://data.open.ac.uk/saou/ontology#numberOfTMAEssays and
  • number of CMA essays: http://data.open.ac.uk/saou/ontology#numberOfECMAEssays

Enjoy some course numbers:

   PREFIX xsd: <http://www.w3.org/2001/XMLSchema#>
   PREFIX cw: <http://courseware.rkbexplorer.com/ontologies/courseware#>
   PREFIX aiiso: <http://purl.org/vocab/aiiso/schema#>
   SELECT 
     (str(?code) as ?CODE)
     (str(?property) as ?PROPERTY)
     (str(?value) as ?VALUE)
   FROM <http://data.open.ac.uk/context/course>
   WHERE {
    [] ?property ?value ;
       aiiso:code ?code;
       a cw:Course .
    FILTER (datatype(?value) in (xsd:integer, xsd:float))
   } order by (?code)

Additionally, now books are well described, see for example The Burial at Thebes

Course locations: names and country codes added
Mon, 04 Nov 2013

Names and country codes have been added to locations of courses.

The following example query will list the details about locations where the course M366 is available:

PREFIX rdfs: <http://www.w3.org/2000/01/rdf-schema#> 
PREFIX mlo: <http://purl.org/net/mlo/>
PREFIX dct: <http://purl.org/dc/terms/>
PREFIX gn: <http://www.geonames.org/ontology#>

SELECT *
FROM <http://data.open.ac.uk/context/course>
WHERE {
  <http://data.open.ac.uk/course/m366> mlo:location ?loc .
   ?loc rdfs:label ?name .
   optional{
      ?loc gn:countryCode ?iso3166 .
      FILTER(datatype(?iso3166)=dct:ISO3166)
   } .
   optional{
      ?loc gn:countryCode ?iso639 .
      FILTER(datatype(?iso639)=dct:ISO639-2)  
   } 
}

Remember, a course description can be reached by following its URI

 http://data.open.ac.uk/course/{lowercase course code}

eg:

 http://data.open.ac.uk/course/m366

New data: short courses
Mon, 04 Nov 2013

"Short courses", as described at the Study at the OU website are now available in the graph http://data.open.ac.uk/context/course

The following query shows the list of short courses currently available:

SELECT ?code ?title
FROM <http://data.open.ac.uk/context/course>
WHERE {
  ?course 
  a <http://data.open.ac.uk/saou/ontology#ShortCourse> ;
  <http://courseware.rkbexplorer.com/ontologies/courseware#is-taught-present> true ;
  <http://purl.org/vocab/aiiso/schema#code> ?code ;
  <http://courseware.rkbexplorer.com/ontologies/courseware#has-title> ?title ;
}